Как заменить теги br на теги в шаблоне XSL?

Предположим, у меня есть простой файл XML:

<data>
  <text>Hello world!&lt;br&gt;Nice to see you all!&lt;br&gt;Goodbye!</text>
</data>

Теперь я хочу заменить все строки &lt;br&gt; строками &#10;, поэтому результат должен быть, например:

<transformed>
  <text>Hello world!&#10;Nice to see you all!&#10;Goodbye!</text>
</transformed>

Как мне это сделать?

Функцию замены XSL легко реализовать (например, в http://geekswithblogs.net/Erik/archive/2008/04/01/120915.aspx), но сложная часть заключается в том, чтобы заставить XSL-преобразователь выводить эти &#10; строк. Я либо получаю невидимый нормальный перевод строки, либо &amp;#10;

Идеальным ответом будет шаблон XSL, который делает свое дело.


xml xpath replace xslt linefeed
person user1180357    schedule 31.01.2012    source источник
comment
&#10; является ссылкой на сущность для символа перевода строки и эквивалентна. Зачем вам это нужно для сериализации с использованием ссылки на сущность? Для парсеров XML оба способа оцениваются одинаково, и это не должно иметь значения.   -  person Mads Hansen    schedule 31.01.2012

Ответы (1)


arrow_upward
1
arrow_downward

Использовать:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="xml" indent="yes"/>

  <xsl:template match="/data">
    <transformed>
      <text>
        <xsl:call-template name="string-replace-all">
          <xsl:with-param name="text" select="text" />
          <xsl:with-param name="replace">&lt;br&gt;</xsl:with-param>
          <xsl:with-param name="by">&amp;#10;</xsl:with-param>
        </xsl:call-template>
      </text>
    </transformed>
  </xsl:template>

  <xsl:template name="string-replace-all">
    <xsl:param name="text" />
    <xsl:param name="replace" />
    <xsl:param name="by" />
    <xsl:choose>
      <xsl:when test="contains($text, $replace)">
        <xsl:value-of select="substring-before($text, $replace)" />
        <xsl:value-of select="$by" disable-output-escaping="yes" />
        <xsl:call-template name="string-replace-all">
          <xsl:with-param name="text" select="substring-after($text,$replace)" />
          <xsl:with-param name="replace" select="$replace" />
          <xsl:with-param name="by" select="$by" />
        </xsl:call-template>
      </xsl:when>
      <xsl:otherwise>
        <xsl:value-of select="$text" />
      </xsl:otherwise>
    </xsl:choose>
  </xsl:template>

</xsl:stylesheet>

выход:

<transformed>
  <text>Hello world!&#10;Nice to see you all!&#10;Goodbye!</text>
</transformed>

NB!:

Установите для атрибута disable-output-escaping значение yes

person Kirill Polishchuk    schedule 31.01.2012
comment
Большое спасибо за быстрый и полный ответ! Этот XSL-файл действительно помогает! - person user1180357; 31.01.2012