Линии графика с использованием разных стилей без файла данных

Следующий код создает график. Мой вопрос: как можно создать эти две строки, используя разные стили, не помещая их в файл данных и используя plot 'plotting_data.dat' index 0 with linespoints linestyle 1, '' index 1 with linespoints linestyle 2

set style line 1 \
    linecolor rgb '#0060ad' \
    linetype 1 linewidth 2 \
    pointtype 7 pointsize 1.5
set style line 2 \
    linecolor rgb '#dd181f' \
    linetype 1 linewidth 2 \
    pointtype 5 pointsize 1.5

# THIS WON'T WORK
# plot '-' index 0 with linespoints linestyle 1, \
#      '-' index 1 with linespoints linestyle 2

# THIS CREATES A PLOT
plot '-' with linespoints linestyle 1
# First data block (index 0)
# X   Y
  1   2
  2   3


# Second index block (index 1)
# X   Y
  3   2
  4   1

Заранее спасибо.


gnuplot
person sofname    schedule 06.01.2020    source источник

Ответы (1)


arrow_upward
2
arrow_downward

Вы не указываете, нужно ли вам отображать данные через '-'. Если вам нужны два графика с данными через '-', вы должны предоставить данные дважды. Проверьте help data.

Есть еще один способ «доставлять» данные вместе с кодом gnuplot, определяя блоки данных. Проверьте help datablocks.

### data in code included
reset session

set style line 1 \
    linecolor rgb '#0060ad' \
    linetype 1 linewidth 2 \
    pointtype 7 pointsize 1.5
set style line 2 \
    linecolor rgb '#dd181f' \
    linetype 1 linewidth 2 \
    pointtype 5 pointsize 1.5

$Data <<EOD
# First data block (index 0)
# X   Y
  1   2
  2   3


# Second index block (index 1)
# X   Y
  3   2
  4   1
EOD

plot $Data index 0 with linespoints linestyle 1, \
     $Data index 1 with linespoints linestyle 2
### end of code
person theozh    schedule 06.01.2020